#include <Arduino.h>
#include <RCSwitch.h>
#include <ArduinoJson.h>
#include <Adafruit_Sensor.h>
#include <DHT.h>

#define RESET_PIN 10
#define SEND_PIN 11
#define RECEIVE_PIN 2
#define DHT11_PIN 12

#define READ_INTERVAL(c) (c*60*1000UL)	// read interval in minutes

const unsigned long readInterval = READ_INTERVAL(5);
unsigned long lastReadTime = -READ_INTERVAL(10);

RCSwitch mySwitch = RCSwitch();
DHT dht = DHT(DHT11_PIN, DHT11);

void readRcSwitch(JsonDocument& jsonDoc);
void readCommand();
void readDht(JsonDocument& jsonDoc);

void setup() {
	pinMode(LED_BUILTIN, OUTPUT);
	pinMode(RESET_PIN, INPUT_PULLUP);

	mySwitch.enableReceive(digitalPinToInterrupt(RECEIVE_PIN));
	mySwitch.enableTransmit(SEND_PIN);
	mySwitch.setRepeatTransmit(10);

	dht.begin();

	Serial.begin(9600);

	delay(1000);
}

void loop() {
	StaticJsonDocument<200> jsonDoc;
	readCommand();
	readRcSwitch(jsonDoc);
	readDht(jsonDoc);
	if (!jsonDoc.isNull()) {
		serializeJson(jsonDoc, Serial);
		Serial.println();
	}
}

void readRcSwitch(JsonDocument& jsonDoc) {
	if (mySwitch.available()) {
		unsigned long value = mySwitch.getReceivedValue();
		mySwitch.resetAvailable();

		if (mySwitch.getReceivedProtocol() == 2) {
			if (value == 637541753L || value == 771759481L) {
				JsonObject motion = jsonDoc.createNestedObject("motion");
				motion["kitchen"] = value == 637541753L ? "on" : "off";
				return;
			}
			if (value == 1879048230L || value == 1879048198L) {
				JsonObject motion = jsonDoc.createNestedObject("motion");
				motion["basement"] = value == 1879048230L ? "on" : "off";
				return;
			}
		}
		JsonObject rcSwitch = jsonDoc.createNestedObject("rcSwitch");
		rcSwitch["protocol"] = mySwitch.getReceivedProtocol();
		rcSwitch["value"] = value;
	}
}

void readCommand() {
	if (Serial.available() > 0) {
		String cmd = Serial.readStringUntil('\n');
		if (cmd == "reset") {
			pinMode(RESET_PIN, OUTPUT);
			digitalWrite(RESET_PIN, LOW);
		}
		StaticJsonDocument<256> jsonDoc;
		DeserializationError err = deserializeJson(jsonDoc, cmd);
		if (err == DeserializationError::Ok) {
			if (jsonDoc.containsKey("rcSwitch")) {
				JsonObject rcSwitch = jsonDoc["rcSwitch"];
				unsigned int protocol = rcSwitch["protocol"];
				if (protocol == 1) {
					mySwitch.setProtocol(protocol);
					char* group = rcSwitch["group"];
					int channel = rcSwitch["channel"];
					if (rcSwitch["state"]) {
						mySwitch.switchOn(group, channel);
					} else {
						mySwitch.switchOff(group, channel);
					}
				} else {
					mySwitch.setProtocol(protocol);
					mySwitch.send(rcSwitch["value"]);
				}
			}
		} else {
			Serial.println(err.c_str());
		}
	}
}

void readDht(JsonDocument& jsonDoc) {
	unsigned long currentTime = millis();
	if ((currentTime - lastReadTime) > readInterval) {
		lastReadTime = currentTime;
		JsonObject dht11 = jsonDoc.createNestedObject("dht11");
		dht11["temperature"] = dht.readTemperature();
		dht11["humidity"] = dht.readHumidity();
	}
}
